home *** CD-ROM | disk | FTP | other *** search
/ CD ROM Paradise Collection 4 / CD ROM Paradise Collection 4 1995 Nov.iso / asm / alib11b.zip / CODE1.ZIP / DISPINFO / DISPINFO.ASM
Assembly Source File  |  1994-10-06  |  9KB  |  391 lines
  1.     page    66,132
  2. comment 
  3. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  4. CHECK_ANSI - check if ANSI active
  5. ;
  6. ; inputs:    none
  7. ; 
  8. ; output:    CF = 1 if no ANSI driver active
  9. ;            CF = 0 if ANSI active
  10. ;* * * * * * * * * * * * * *
  11. 
  12.     public    CHECK_ANSI
  13. CHECK_ANSI        PROC    FAR
  14.      APUSH   AX,DX,DS
  15.      MOV     AX,CS
  16.      MOV     DS,AX
  17.      CALL    console_input
  18.      CALL    CHECK_ANSI_cont1
  19.  
  20.      DB         1BH,'[6n$'
  21. ;
  22. CHECK_ANSI_cont1:
  23.      POP     DX
  24.      CALL    console_output
  25.      MOV     AH,0Bh        ;check STDIN status, al=ff if input
  26.      INT     21h
  27.      CMP     AL,0FFh
  28.      JZ      IA_1        ;jmp if char. is ready from ansi call
  29.      CALL    isansi_cont2
  30.  
  31.      db         0dH,'    ',0dH,'$'
  32.  
  33. isansi_cont2:
  34.      POP    DX
  35.      CALL    console_output
  36.      STC
  37.      JMP     IA_2
  38. IA_1:
  39.      CALL    console_input
  40.      CLC
  41. IA_2:
  42.      APOP    DS,DX,AX
  43.      JB      NO_ANSI
  44.      CLC
  45.      RETF
  46. NO_ANSI:
  47.      STC
  48.      RETF
  49. CHECK_ANSI    ENDP
  50. ;------------------------------
  51. console_output:
  52.      MOV     AH,09
  53.      INT     21h
  54.      RET
  55.  
  56. console_input:
  57.      MOV     AH,06
  58.      MOV     DL,0FFh
  59.      INT     21h
  60.      JNZ     console_input
  61.      RET
  62.  
  63. comment 
  64. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  65. DISPLAY_INFO - determine display information
  66. ;
  67. ; inputs:    none
  68. ;            
  69. ; output:    AL = screen rows
  70. ;            CH = screen columns
  71. ;            BX:[SI] = video buffer address
  72. ;            register DX is modified
  73. ;* * * * * * * * * * * * * *
  74. 
  75.     public    display_info
  76. display_info:
  77.     push    es
  78.     call    detectvid            ;get video type
  79.     cmp    ax,0
  80.     je    display_info_exit        ;exit if no display
  81. ;
  82. ; check for special case, dual display and alternate monochrome active
  83. ;
  84.     mov    bx,0
  85.     mov    es,bx
  86.     cmp    al,3                ;check if color display
  87.     jb    mono_port            ;jmp if mono
  88.     cmp    word ptr es:[463h],3d4h        ;verify color port active
  89.     je    port_ck_end            ;jmp if port ok
  90.     mov    ax,2                ;force monochrome display
  91.     jmp    port_ck_end
  92. mono_port:
  93.     cmp    word ptr es:[463h],3b4h        ;verify mono port active
  94.     je    port_ck_end
  95.     mov    ax,5                ;force cga color
  96. port_ck_end:
  97.     
  98.     push    ax
  99.     mov    ax,0500h
  100.     int    10h                ;force page 0
  101.  
  102.     mov    ax,0
  103.     mov    es,ax
  104.     mov    bh,es:[449h]            ;get display mode
  105.     pop    ax
  106.  
  107.     cmp    al,6
  108.     jbe    get_rows            ;jmp if mono or cga
  109.     cmp    al,9
  110.     je    get_rows            ;jmp if cga compatable
  111.  
  112.     push    ax
  113.     push    bx
  114.     mov    ax,1130h
  115.     mov    bh,0
  116.     push    es
  117.     int    10h
  118.     pop    es
  119.     pop    bx
  120.     pop    ax
  121.     mov    bl,dl                ;move rows to -bl-
  122.     jmp    rows_ok      
  123.  
  124. get_rows:
  125.     mov    bl,es:[484h]            ;get rows
  126.     cmp    bl,0
  127.     je    fix_rows            ;jmp if row info bad
  128.     cmp    bl,80
  129.     jb    rows_ok                ;jmp if row info found
  130. fix_rows:
  131.     mov    bl,24                ;force 25 lines on screen
  132. rows_ok:
  133.     inc    bl
  134. get_columns:
  135.     mov    cx,word ptr es:[44ah]        ;get columns on display
  136. display_info_exit:
  137.     pop    es
  138.     ret    
  139. comment 
  140. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  141. DETECTVID -  determine display type
  142. ;
  143. ;  inputs: none
  144. ;  
  145. ;  outputs:  ax = 0  no display
  146. ;                 1  monochrome
  147. ;                 2  hercules 
  148. ;                 3  cga digital (mono)
  149. ;                 4  cga analog  (mono)
  150. ;                 5  cga analog (color)
  151. ;                 6  ega mono
  152. ;                 7  ega color 64k
  153. ;                 8  ega color 64k+
  154. ;                 9  cga compatable
  155. ;                10  vga mono
  156. ;                11  vga color 
  157. ;* * * * * * * * * * * * * *
  158. 
  159. vga_mono    equ    10
  160. vga_color    equ    11
  161. monochrome    equ    1
  162. hercules    equ    2
  163.  
  164.     public    detectvid
  165. detectvid:
  166.     mov ax,1a00h          ;used by mcga and vga
  167.     int 10h
  168.     cmp al,1ah            ;if al = 1ah then mcga or vga is present
  169.     jnz dt1
  170.     cmp bl,7              ;if active monitor is monochrome vga
  171.     jnz do1
  172.     mov ax,vga_mono       ;mono vga found
  173.     ret
  174. do1:
  175.     cmp bl,8              ;if active monitor is color vga
  176.     jnz do2
  177.     mov ax,vga_color      ;color vga found
  178.     ret
  179. do2:
  180.     cmp bl,0ah            ;if digital mcga
  181.     jnz do3
  182.     mov ax,3              ;digital mcga found
  183.     ret
  184. do3:
  185.     cmp bl,0bh            ;if monochrome mcga
  186.     jnz do4
  187.     mov ax,4              ;analog monochrome mcga found
  188.     ret
  189. do4:
  190.     cmp bl,0ch            ;if color mcga
  191.     jnz dt1
  192.     mov ax,5              ;analog color mcga found
  193.     ret
  194. dt1:
  195.     mov ah,12h            ;used by ega
  196.     mov bl,10h
  197.     int 10h
  198.     cmp bl,10h            ;if bl is not 10h then ega is present
  199.     jz dt2
  200.     cmp bh,1              ;if monochrome ega
  201.     jnz do5
  202.     mov ax,6              ;monochrome ega
  203.     ret
  204. do5:
  205.     or bl,bl              ;or 64k ega board
  206.     jnz do6
  207.     mov ax,7              ;color ega with 64k memory
  208.     ret
  209. do6:
  210.     mov ax,8              ;color ega with > 64k memory
  211.     ret
  212. dt2:
  213.     mov dx,3d4h           ;address for cga crtc
  214.     call find6845         ;look for controller
  215.     jnc dt3               ;if clear then cga present
  216.     mov dx,3b4h           ;address for hercules or mda
  217.     call find6845         ;look for controller
  218.     jnc dt4               ;jump if hercules or mda present
  219.     mov ax,0              ;unable to detect card
  220.     ret
  221. dt3:
  222.     mov ax,9              ;cga compatible present
  223.     ret
  224. dt4:
  225.     mov dl,0bah           ;read this port
  226.     in al,dx
  227.     and al,80h            ;get value in ah
  228.     mov ah,al
  229.     mov cx,8000h          ;loop this many times
  230. dt5:
  231.     in al,dx              ;read port
  232.     and al,80h
  233.     cmp ah,al             ;has value changed
  234.     loopz dt5
  235.     jcxz dt6              ;if cx = 0 then mda is present
  236.     mov ax,hercules       ;hercules card
  237.     ret
  238. dt6:
  239.     mov ax,monochrome     ;mda card
  240.     ret
  241. ;-------------------------------------------------------------------------
  242.     public    find6845
  243. find6845 proc near        ;find out if crtc is present
  244.     mov al,0fh            ;select reg ( cursor low )
  245.     out dx,al
  246.     inc dx
  247.     in al,dx              ;al = cursor low position
  248.     mov ah,al             ;save value in ah
  249.     mov al,66h            ;arbitrary value
  250.     out dx,al             ;write to crtc
  251.     mov cx,100h
  252. f61:
  253.     loop f61              ;wait for response
  254.     in al,dx
  255.     xchg ah,al            ;ah = returned value
  256.     out dx,al             ;reset port
  257.     cmp ah,66h            ;was value unchanged
  258.     je f62
  259.     stc                   ;if no response
  260. f62:
  261.     ret
  262. find6845 endp
  263.  
  264. comment 
  265. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  266. FIND_DISPLAY_SEGMENT  -  scan for current display buffer segment
  267. ;
  268. ;  inputs:   display mode 3 or 7 must be set and display page must = 0
  269. ;  
  270. ;  output:   display_segment is set
  271. ;
  272. ;* * * * * * * * * * * * * *
  273. 
  274.     public    find_display_segment
  275. find_display_segment:
  276.     push    ax
  277.     push    bx
  278.     push    es
  279.     cli
  280.     mov    ax,0b000h        ;display seg?
  281.     mov    es,ax
  282.     mov    bx,es:[0]        ;save current data
  283.     mov    word ptr es:[0],0101h    ;store code 0101 at b000
  284.     mov    ax,0b800h        ;move to b800
  285.     mov    es,ax
  286.     mov    cx,es:[0]        ;save current data
  287.     mov    word ptr es:[0],0303h    ;store code 0303 at b800
  288.  
  289.     push    bx
  290.     push    cx
  291.  
  292.     mov    ah,3
  293.     mov    bh,0
  294.     int    10h            ;read cursor position -> dx
  295.     mov    cx,dx            ;save cursor posn
  296.  
  297.     mov    ah,2            ;move
  298.     mov    bh,0            ; cursor
  299.     mov    dx,0            ;   to page 0
  300.     int    10h            ;     top left
  301.  
  302.     mov    ah,8            ;read
  303.     mov    bh,0            ;  data
  304.     int    10h            ;    at cursor
  305. ;
  306. ; restore cursor position
  307. ;
  308.     push    ax            ;save data read
  309.     mov    dx,cx
  310.     mov    ah,2
  311.     int    10h
  312.     pop    ax            ;restore data read 
  313. ;
  314. ; restore origional display buffer data
  315. ;
  316.     pop    cx            ;  origional
  317.     pop    bx            ;   display contents
  318.     push    ax            ;save data read
  319.     mov    ax,0b000h
  320.     mov    es,ax
  321.     mov    word ptr es:[0],bx
  322.     mov    ax,0b800h
  323.     mov    es,ax
  324.     mov    word ptr es:[0],cx
  325. ;
  326. ; recover data read from display to determine segment location
  327. ;    
  328.     pop    ax
  329.     cmp    ax,0101h
  330.     je    use_b000
  331. use_b800:
  332.     mov    ax,0b800h
  333.     jmp    set_seg_cont
  334. use_b000:
  335.     mov    ax,0b000h
  336. set_seg_cont:
  337.     mov    lib_info.crt_seg,ax
  338.     sti
  339.     pop    es
  340.     pop    bx
  341.     pop    ax
  342.     ret
  343.  
  344. ;░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░
  345. ; set_display_flags - determine cga snow flag and mono flag default settings
  346. ;  inputs: crt_info data stored in data base
  347. ;  output: al = mono flag (1=mono)
  348. ;          dx = snow flag (cga port if cga)
  349. ;
  350. set_display_flags:
  351.     sub    ax,ax
  352.     mov    es,ax
  353. ;
  354. ; get display mode
  355. ;
  356.     mov    al,byte ptr es:[449h]    ;get display mode
  357.     mov    lib_info.crt_mode,al    
  358. ;
  359. ; force display page zero
  360. ;
  361.     mov    ah,5
  362.     mov    al,0            ;page 0
  363.     int    10h    
  364. ;
  365. ; set cga flag
  366. ;
  367.     mov    al,lib_info.crt_type
  368.     cmp    al,3
  369.     jb    mono_display
  370.     cmp    al,5
  371.     jbe    cga_display
  372.     cmp    al,9
  373.     je    cga_display
  374. ;
  375. ; we must have a color display, it is not a cga or mono
  376. ;
  377.     mov    al,0
  378.     mov    dx,0
  379.     jmp    sdf_exit    
  380. ;
  381. mono_display:
  382.     mov    al,1
  383.     mov    dx,0
  384.     jmp    sdf_exit
  385.     
  386. cga_display:
  387.     mov    al,0
  388.     mov    dx,3dah
  389. sdf_exit:
  390.     ret
  391.